AccessVBA/実例集

事例集 †

事例集
フォームの操作
レポートの操作
レコードを検索する
レコードを抽出する
レコードを削除する
- サブレコード上のレコードを削除する
- 特定のレコードを一度に削除する(SQL)
入力値のチェック
アプリケーション構築のヒント

フォームの操作 †

フォームを開いたり閉じたりする作業は、DoCmdオブジェクトのOpenFormメソッドとCloseメソッドを使います。

指定したフォームを開く †

書式

DoCmd.OpenForm formname, view, filtername, wherecondition, datamode, windowmode, openargs

formname    :開くフォームの名前
view        :(省略可)ビュー
             acDesign         :デザインビュー
             acFormDS         :データシートビュー
             acFormPivotChart :ピボットグラフビュー
             acFormPibotTable :ピボットテーブルビュー
             acNormal         :フォームビュー(既定値)
             acPreview        :印刷プレビュー
filtername  :(省略可)レコードを抽出条件を指定したクエリ名
wherecondition :レコード抽出条件を表す文字列
datamode    :(省略可)データモード
             acFormAdd        :追加
             acFormEdit       :編集
             acFormPropetySetting  :編集(既定値)
             acFormReadOnly        :読み取り専用
windowmode  :(省略可)ウィンドウモード
             acDialog         :ダイアログ
             acHidden         :非表示
             aclcon           :アイコン
             acWindowNormal   :標準(既定値)
openargs    :(省略可)開くフォームに渡す文字列式

例1
```
DoCmd.OpenForm "F_顧客"
```

抽出したレコードをフォームに表示する。 †

例1
[Q_東京都]クエリを使って抽出したレコードを[F_顧客フォーム]に表示する。
```
DoCmd.OpenForm "F_顧客", , "Q_東京都"
```

例2
wherecondition引数に条件を書いて抽出する。
```
DoCmd.OpenForm "F_顧客",,,"都道府県 = '東京都'"
```

新規レコード追加用にフォームを開く †

Private Sub cmd顧客_Click()
  DoCmd.OpenForm "F_顧客", , , , acFormAdd
End Sub

フォームの標題を変更する †

フォームを作成して、クリック時のプロパティにOpenArgsを渡すように設定

Private Sub cmd追加_Click()
  DoCmd.OpenForm "F_顧客", , , , acFormAdd, , "追加"
End Sub

Private Sub cmd編集_Click()
  DoCmd.OpenForm "F_顧客", , , , acFormEdit, , "編集"
End Sub

Private Sub cmd読み取り_Click()
  DoCmd.OpenForm "F_顧客", , , , acFormReadOnly, , "読み取り"
End Sub

「F_顧客」の開く時のプロパティに下記のプロシージャを作成 Private Sub Form_Open(Cancel As Integer)

 Select Case Me.OpenArgs
 Case "追加"
   Me.Caption = "F_顧客　(追加モード)"
 Case "編集"
   Me.Caption = "F_顧客　(編集モード)"
 Case "読み取り"
   Me.Caption = "F_顧客  (読み取りモード)"
 Case Else
   Me.Caption = "F_顧客"
 End Select

End Sub

フォームの位置を指定する †

DoCMDオブジェクトのMoveSizeメソッドを利用して、カレントオブジェクトの表示位置や大きさを指定する事ができます。

書式

DoCMD.MoveSize right, down, width, height

right   :ウィンドウの左隅の水平位置.作業ウィンドウの左端からの距離で指定
down    :ウィンドウの左隅の垂直位置.作業ウィンドウの上橋からの距離で指定
width   :ウィンドウの幅
height  :ウィンドウの高さ

例
ウィンドウの幅を10cm、高さを5cmにする
```
DoCmd.MoveSize ,,10 * 567, 5 * 567
```

参考
MoveSizeメソッドの引数は、twip単位で指定してください。
twipは、画面の長さを表す時に使う単位です。
1cmは567twip
1inchは440twip
1ピクセルは15twip

フォームの大きさで表示する †

フォームの[サイズ自動修正]プロパティが「いいえ」の場合は、最後に閉じたときのウィンドウの大きさでフォームが開きます。

書式
```
DoCmd.RunCommand acCmdSizeToFitForm
```

例

Private Sub cmdサイズ変更_click()
  DoCmd.RunCommand acCmdSizeToFitForm
End Sub

予定時刻にアラームを表示する †

設定

オブジェクト     名前      プロパティ      値
フォーム                   タイマ間隔      1000
テキストボックス 時間      書式            時刻(S)

例

フォーム      
Private Sub Form_Timer()
  If time() = Me!時間 Then
    Beep
    MsgBox "アラーム"
  End If
End Sub

フォームを閉じる †

書式

DoCmc.Close objecttype, objectnae, save

objecttype   :(省略可)閉じるオブジェクトタイプ
              acDataAccessPage  :データアクセスページ
              acDefault         :カレントオブジェクト(既定値)
              acDiagram         :ダイアグラム
              acForm            :フォーム
              acFunction        :関数
              acMacro           :マクロ
              acModule          :モジュール
              acQuery           :クエリ
              acReport          :レポート
              acServerView      :サーバービュー
              acStoredProcedure :ストアアドプロシージャ
              acTable           :テーブル
objectname   :(省略可)閉じるオブジェクト名
save         :(省略可)閉じる時にオブジェクトを保存するかどうか
              acSaveNo   :保存しない
              acPrompt   :変更があったとき確認する(既定値)
              acSaveYes  :保存する.確認はしない

フォームを連動させる †

フォームを開くとき、FormOpenプロシージャに別のフォームも一緒に開く処理を書いておけば、
2つのフォームを一緒に開くことができます。

Private Sub Form_Open(Cancel As Integer)
  DoCmd.OpenForm "F_顧客", acFormDS
End Sub
Private Sub Form_Close()
  DoCmd.Close acForm, "F_顧客"
End Sub

2つのフォームを連動させる †

[レコードの移動時]プロパティに下記のプロシージャを作成

Private Sub Form_Current()

 DoCmd.OpenForm "F_注文履歴", acFormDS, , "顧客ID =" & Me!顧客ID '-----------①
 Me.SetFocus   '-------------------------------------------------------------②

End Sub

①[F_注文履歴]フォームをデータシートビューで開く,[顧客ID]フィールドがメインフォームの[顧客ID]と同じレコードだけ抽出
②プログラムを実行しているフォームにフォーカスを移動する。

フォームにキャンセルボタンを追加する †

キャンセルボタンを作成するには、[キャンセルボタン]プロパティを「はい」にしてください。
キャンセルボタンは、フォームに一つだけ作成する事ができます。

例
「Esc」キーを押すと、編集操作を取り消して、フォームを閉じます。

Private Sub cmdキャンセル_Click()
  If Me.Dirty Then
    DoCmd.RunCommand acCmdUndo
  End If
  DoCmd.Close
End Sub

一定時間経過後にフォームを閉じる †

フォームの[タイマ間隔]を「5000」に設定 Private Sub Form_Timer()

 DoCmd.Close

End Sub

Timer()
1000/1000秒とは、1秒のことです。
5000/1000秒とは、5秒のことです。

レポートの操作 †

DoCmdオブジェクトのOpenReportメソッドを利用すると、指定したレポートをプリンタに印刷したり、プレビューしたりすることができます。
OpenReportメソッドは、マクロの[レポートを開く]アクションと同じ処理を行います。

書式

DoCmd.OpenReport reportname, view, filtername, wherecondition, windowmode, openargs

reportname     :開くレポート名
view           :(省略可)ビュー
                acViewDesign     :デザインビュー
                acViewNormal     :プリンタに出力(既定値)
                acViewPreview    :印刷プレビュー
filtername     :(省略可)レコード抽出条件を指定したクエリ名
wherecondition :(省略可)レコード抽出条件を表す文字列
windowmode     :(省略可)ウィンドウモード
                acDialog         :ダイアログ
                acHidden         :非表示
                acIcon           :アイコン
                acWindowNormal   :標準(既定値)
openargs       :(省略可)開くレポートに渡す文字列

例

Private Sub cmdプレビュー_Click()
  DoCmd.OpenReport "R_東京都", acViewPreview
End Sub

Private Sub cmd印刷_Click()
  DoCmd.OpenReport "R_東京都"
End Sub

倍率を指定してプレビューする †

プレビューの倍率を指定するには、DoCmdオブジェクトのRunCommandメソッドを使って[ズーム]コマンドを実行してください。

例

Private Sub ズーム_Click()
  DoCmd.OpenReport "Q_東京都", acViewPreview
  DoCmd.MoveSize , , 18 * 567   '----------------------ウィンドウの幅を18cmにする
  DoCmd.RunCommand acCmdZoom75  '----------------------[ズーム75%]コマンドを実行する
End Sub

レポートのタイトルを印刷時に指定する †

メインフォームで印刷プレビューをクリックした時のプロシージャにopenargs引数を付ける

Private Sub cmd大阪府_Click()
  DoCmd.OpenReport "R_顧客", acViewPreview, , "都道府県 = '大阪府'", , "大阪府"
End Sub
Private Sub cmd東京都_Click()
  DoCmd.OpenReport "R_顧客", acViewPreview, , "都道府県 = '東京都'", , "東京都"
End Sub
Private Sub cmd顧客一覧_Click()
  DoCmd.OpenReport "R_顧客", acViewPreview
End Sub

[R_顧客]レポートの開くときのプロパティに下記のプロシージャ作成

Private Sub Report_Open(Cancel As Integer)
  If OpenArgs <> "" Then
    Me!ラベル19.Caption = OpenArgs
  Else
    Me!ラベル19.Caption = "顧客一覧"
  End If
End Sub

1レコードごとに色分けして印刷する †

ReportオブジェクトのSectionプロパティを利用すると、各セクションのプロパティを参照する事ができます。

書式

object.Section(index)

object   :Acessオブジェクト
index    :参照するセクション
          acDetail        :詳細セクション
          acHeader        :ヘッダーセクション
          acFooter        :フッターセクション
          acPageHeader    :ページヘッダーセクション
          acPageFooter    :ページフッターセクション
          acGroupLevel1Header :グループレベル1のヘッダーセクション(レポートのみ)
          acGroupLevel1Footer :グループレベル1のフッターセクション(レポートのみ

例
カレントオブジェクトの[詳細]セクションの[背景色]プロパティを参照する。
```
Me.Section(acDetail).BackColor
```

詳細セクションの「フォーマット時」プロパティにプロシージャを作成

Private Sub 詳細_Format(Cancel As Integer, FormatCount As Integer)
  Static flgColor As Boolean
  
  If flgColor = True Then
    Me.Section(acDetail).BackColor = RGB(255, 255, 255)
  Else
    Me.Section(acDetail).BackColor = RGB(230, 230, 230)
  End If
  flgColor = Not flgColor
End Sub

印刷前に「ページ設定」ダイアログボックスを表示する †

Private Sub cmd印刷_Click()
  DoCmd.SelectObject acReport, "R_顧客", True  '--------①
  DoCmd.RunCommand acCmdPageSetup   '-------------------②
  DoCmd.OpenReport "R_顧客", acViewPreview '------------③
End Sub

①データベースウィンドウで「R_顧客」を選択
②「ページ設定」ダイアログボックスを表示する
③「R_顧客」レポートをプレビューする

DoCmdオブジェクトのSelectObjectメソッドは、マクロの「オブジェクトの選択」アクションと同じ処理を行います。 †

書式

DoCmd.SelectObject objecttype, objectname, indatabasewindow

objecttype    :選択するオブジェクトの種類
               acDataAccessPage   :データアクセスページ
               acDiagram          :ダイアグラム
               acForm             :フォーム
               acFunction         :関数
               acMacro            :マクロ
               acModule           :モジュール
               acQuery            :クエリ
               acReport           :レポート
               acServerView       :サーバービュー
               acStoredProcedure  :ストアドプロシージャ
               acTable            :テーブル
objectname    :(省略可)選択するオブジェクトの名前
indatabasewindow :(省略可)データベースウィンドウで選択するかどうか
                  True  :データベースウィンドウ内で選択
                  False :開いているオブジェクトを選択(既定値)

印刷する前に[印刷]ダイアログボックスを表示する。 †

Private Sub cmd印刷_Click()
  DoCmd.SelectObject acReport, "R_顧客", True  '--------①
  DoCmd.RunCommand acCmdPring       '-------------------②
End Sub

①データベースウィンドウで「R_顧客」を選択
②[印刷]ダイアログボックスを表示する

印刷するデータがない時に処理を中止する †

[R_顧客]レポートの「空データの時」プロパティに下記を作成
Cancel引数をTrueにすると、このイベントを取り消す事ができます。 Private Sub Report_NoData(Cancel As Integer)
```
 Cancel = True
```
End Sub

[印刷]ボタンのクリック時プロパティに下記のプロシージャを作成

Private Sub cmd印刷_Click()
On Error GoTo Err_cmd印刷_Click
  DoCmd.OpenReport "Q_顧客", acViewPreview, , "都道府県='" & Me!都道府県 & "'" 

exit_cmd印刷_Click:
  Exit Sub

Err_cmd印刷_Click:
  Select Case Err.Number
  Case 2501
    MsgBox "印刷するデータがありません。", vbOKOnly + vbInformation, "レポートを開く"
  Case Else
  Beep
  MsgBox Err.Number & " : " & Err.Description
  End Select
End Sub

レコードを検索する †

フォームのレコードソースを検索する場合は、AccessVBA/DAOのRecordsetオブジェクトを利用してください。
AccessVBA/ADOのRecordsetオブジェクトでは、フォームのソースを扱う事ができません。

検索ダイアログボックスを利用する †

Public Sub cmd検索_Click()
  Me!都道府県.SetFocus
  DoCmd.RunCommand acCmdFind
End Sub

フォームに検索機能を追加する †

フォームにレコードソースは、RecordsetCloneプロパティで参照できます。
これをもとにRecordsetオブジェクトを作成すると、RecordsetオブジェクトのFind系のメソッドを利用して、レコードを検索することができます。
ただし、フォームのレコードソースと、RecordsetCloneプロパティをもとに作成したRecordsetオブジェクトは別のレコードセットです。
Bookmarkプロパティを利用して、両方のカレントコードの同期をとる処理が必要になります。

例

Public Sub cmd検索02_Click()
  Dim rs As DAO.Recordset
  Set rs = Me.RecordsetClone
  rs.FindFirst "顧客ID = " & Me!txtキー
  If rs.NoMatch Then
    Beep
    MsgBox "見つかりません"
  Else
    Me.Bookmark = rs.Bookmark  '------①
  End If
End Sub

①検索したレコードをフォームに表示する。

コンボボックスの値を使って検索する †

検索する値がコンボボックスうで選択できれば便利です。
コンボボックスで値を選択すると、AfterUpdateイベントが発生します。
このときに検索を実行するように、プログラムを作成してください。

コンボボックスの作成

プロパティ          値
値集合タイプ        テーブル/クエリ
値集合ソース        T_顧客
列数                3
列幅                0cm;0cm;1cm
連結列              3

コンボボックスの更新後処理のプロパティにプロシージャ作成

Public Sub cboキー_AfterUpdate()
  Dim rs As DAO.Recordset
  Set rs = Me.RecordsetClone
  rs.FindFirst "氏名 = '" & Me!cboキー & "'"
  Me.Bookmark = rs.Bookmark
  rs.Close: Set rs = Nothing
End Sub

あいまいな条件で検索する †

テキスト型のフィールドを使って検索するとき、検索条件にLike演算子を利用して、あいまいな条件でレコード検索します。

Public Sub cmd検索02_Click()
  Dim rs As DAO.Recordset
  Set rs = Me.RecordsetClone
  rs.FindFirst "都道府県 Like '" & Me!txtキー & "*'"
  If rs.NoMatch Then
    Beep
    MsgBox "見つかりません"
  Else
    Me.Bookmark = rs.Bookmark
  End If
End Sub

連続して検索する †

先頭を検索ボタンはFindFirst、次を検索ボタンはFindNextで検索するようにする。

Public Sub cmd先頭を検索_Click()
  Dim rs As DAO.Recordset
  Set rs = Me.RecordsetClone
  rs.FindFirst "都道府県 Like '" & Me!txtキー & "*'"
  If rs.NoMatch Then
    Beep
    MsgBox "見つかりません"
  Else
    Me.Bookmark = rs.Bookmark
  End If
End Sub
Public Sub cmd次を検索_Click()
  Dim rs As DAO.Recordset
  Set rs = Me.RecordsetClone
  rs.Bookmark = Me.Bookmark
  rs.FindNext "都道府県 Like '" & Me!txtキー & "*'"
  If rs.NoMatch Then
    Beep
    MsgBox "最後のレコードまで検索しました"
  Else
    Me.Bookmark = rs.Bookmark
  End If
End Sub

独自の検索置換パネルを作成する †

下記の処理で作成する事ができます。
フォームのRefreshメソッドを利用すると、フォーム上で行った編集を保存する事ができます。

フォーム上のコントロールに置換する値を代入する
フォーム上の編集結果をレコードソースに保存する

Private Sub Form_Close()
  DoCmd.Close acForm, "F_顧客"
End Sub

Private Sub Form_Open(Cancel As Integer)
  DoCmd.OpenForm "F_顧客"
  DoCmd.MoveSize 3 * 567, 11 * 567
End Sub
Private Sub cmd先頭_Click()
  Dim rs As DAO.Recordset
  
  Set rs = Forms!F_顧客.RecordsetClone
  Select Case Me!cboフィールド
    Case "顧客ID"
      rs.FindFirst "顧客ID = " & Me!txt検索
    Case "氏名"
      rs.FindFirst "氏名 Like '" & Me!txt検索 & "*'"
  End Select
    
  If rs.NoMatch Then
    Beep
    MsgBox "見つかりません"
  Else
    Forms!F_顧客.Bookmark = rs.Bookmark
  End If
  
  rs.Clone: Set rs = Nothing
End Sub

Private Sub cmd次_Click()
  Dim rs As DAO.Recordset
  Set rs = Forms!F_顧客.RecordsetClone
  rs.Bookmark = Forms!F_顧客.Bookmark
  
  Select Case Me!cboフィールド
    Case "顧客ID"
      rs.FindNext "顧客ID = " & Me!検索
    Case "氏名"
      rs.FindNext "氏名 like '" & Me!txt検索 & "*'"
  End Select
    
  If rs.NoMatch Then
    Beep
    MsgBox "最後まで検索しました。"
  Else
    Forms!F_顧客.Bookmark = rs.Bookmark
  End If
  rs.Clone: Set rs = Nothing
End Sub

Private Sub cmd置換_Click()
  Select Case Me!cboフィールド
    Case "顧客ID"
      Forms!F_顧客!顧客ID = Me!txt置換
    Case "氏名"
      Forms!F_顧客!氏名 = Me!txt置換
  End Select
  
  Forms!F_顧客.Refresh
  
  Call cmd次_Click
End Sub

Private Sub cmdキャンセル_Click()
  DoCmd.Close
End Sub

レコードを抽出する †

フォームにフィルタ機能を追加 †

フォームのFilterプロパティとFilterOnプロパティを利用して、抽出機能を作成する事ができます。

書式

form.Filter = criteria

criteria  :抽出条件を表す文字列

FilterOnプロパティ Filterプロパティに設定したフィルタを適用するかどうかを決めるプロパティです。
Tureにすると、フィルタを適応して抽出する事ができます。Flaseにした場合は、フィルタを解除します。

例

Private Sub cmd抽出_Click()
  If IsNull(Me!txt条件) Then
    Beep
    MsgBox "抽出する値を入力してください。", vbOKOnly + vbCritical, "抽出"
    Exit Sub
  End If 

  Me.Filter = "都道府県 = '" & Me!txt条件 & "'"
  Me.FilterOn = True

  If Me.Recordset.RecordCount = 0 Then
    Beep
    MsgBox "該当するレコードがありません", vbOKOnly + vbInformation, "抽出"
  End If
End Sub

Private Sub cmd解除_Click()
  Me.FilterOn = False
End Sub

抽出したレコードをリストボックスに表示する †

リストボックスの[列数]と[列幅]を適切な値に変更してから

Private Sub cmd抽出_Click()
  Me!lst結果.RowSource = "select * from T_顧客 WHERE 都道府県 = '" & Me!txt条件 & "'"
  Me!lst結果.Requery
End Sub

Private Sub cmd解除_Click()
  Me!txt条件 = Null
  Me!lst結果.RowSource = ""
  Me!lst結果.Requery
End Sub

抽出したレコードをコンボボックスに表示 †

Private Sub lst条件_Click()
  Me!cbo結果.RowSource = "SELECT 氏名,顧客ID,都道府県 FROM T_顧客 WHERE 都道府県 = '" & Me!lst条件 & "'"
  Me!cbo結果.Requery
End Sub

抽出したレコードをサブフォームに表示する †

Private Sub Form_Open(Cancel As Integer)
  Call cmd抽出_Click
End Sub

Private Sub cmd抽出_Click()
  Me!sub結果.Form.Filter = "都道府県 = '" & Me!txt条件 & "'"
  Me!sub結果.Form.FilterOn = True
End Sub

Private Sub cmd解除_Click()
  Me!txt条件 = Null
  Call cmd抽出_Click
End Sub

複数の条件を使って検索する †

タブコントロールを使って抽出 †

タブコントロールを使って、複数のページを持ったシステム手帳のような仕切りページを作る事ができます。

サブフォームのソースオブジェクト作成

[ﾌﾘｶﾞﾝ]フィールドの先頭文字がラベルの標題(Caption)プロパティの値と等しいレコードを抽出するクエリを作成
サブフォーム(sub結果)のソースオブジェクトに設定しておく

オブジェクトの設定

オブジェクト          名前       プロパティ          値
ラベル                ラベル     標題                ｢ｱ-ｵ]*
ページ                page0      標題                あ
                                 ページインデックス  0
                      page1      標題                い
                                 ページインデックス  1
                      ・
                      ・
サブフォーム          sub結果

タブコントロールの[変更時/Change]プロパティにプロシージャを作成 Private Sub tabﾌﾘｶﾞﾅ_Change()

 Select Case Me!tabﾌﾘｶﾞﾅ
   Case 0: Me!ラベル.Caption = "[ｱ-ｵ]*"
   Case 1: Me!ラベル.Caption = "[ｶ-ｺ]*"
   Case 2: Me!ラベル.Caption = "[ｻ-ｿ]*"
   Case 3: Me!ラベル.Caption = "[ﾀ-ﾄ]*"
   Case 4: Me!ラベル.Caption = "[ﾅ-ﾉ]*"
   Case 5: Me!ラベル.Caption = "[ﾊ-ﾎ]*"
   Case 6: Me!ラベル.Caption = "[ﾏ-ﾓ]*"
   Case 7: Me!ラベル.Caption = "[ﾔ-ﾖ]*"
   Case 8: Me!ラベル.Caption = "[ﾗ-ﾛ]*"
   Case 9: Me!ラベル.Caption = "[ﾜ-ﾝ]*"
   Case 10: Me!ラベル.Caption = "*"
 End Select
 Me!sub結果.Requery     '------------------------①

End Sub

①サブフォームの再クエリを実行する。

トグルボタンを使って抽出する †

オプショングループでフレームを配置してから、その中にトグルボタンを追加していく

ボタンなどの「サイズ・配置」を揃えたい †

揃えたいオブジェクトを全て選択して、「右クリック」⇒「サイズ」「配置」

[更新後処理/AfterUpdate]プロパティにプロシージャ作成

Private Sub fra条件_AfterUpdate()
  Dim criteria As String
  
  Select Case Me!fra条件
    Case 1: criteria = "ﾌﾘｶﾞﾅ like '[ｱ-ｵ]*'"
    Case 2: criteria = "ﾌﾘｶﾞﾅ like '[ｶ-ｺﾞ]*'"
    Case 3: criteria = "ﾌﾘｶﾞﾅ like '[ｻ-ｿﾞ]*'"
    Case 4: criteria = "ﾌﾘｶﾞﾅ like '[ﾀ-ﾄﾞ]*'"
    Case 5: criteria = "ﾌﾘｶﾞﾅ like '[ﾅ-ﾉ]*'"
    Case 6: criteria = "ﾌﾘｶﾞﾅ like '[ﾊ-ﾎﾟ]*'"
    Case 7: criteria = "ﾌﾘｶﾞﾅ like '[ﾏ-ﾓ]*'"
    Case 8: criteria = "ﾌﾘｶﾞﾅ like '[ﾔ-ﾖ]*'"
    Case 9: criteria = "ﾌﾘｶﾞﾅ like '[ﾗ-ﾛ]*'"
    Case 10: criteria = "ﾌﾘｶﾞﾅ like '[ﾜ-ﾝ]*'"
    Case 11: criteria = "ﾌﾘｶﾞﾅ like '*'"
  End Select
  
  Me!sub結果.Form.Filter = criteria
  Me!sub結果.Form.FilterOn = True
End Sub

フォームに並べ替え機能を追加する †

Private Sub fra並べ替え_AfterUpdate()
  Debug.Print Me!fra並べ替え
  Select Case Me!fra並べ替え
    Case 1: Me!sub結果.Form.OrderBy = "生年月日 ASC"
    Case 2: Me!sub結果.Form.OrderBy = "生年月日 DESC"
  End Select
  Me!sub結果.Form.OrderByOn = True
End Sub

レコードを削除する †

サブレコード上のレコードを削除する †

サブフォームのレコードソースをもとにRecordsetオブジェクトを作成すると、Deleteメソッドを使って、サブフォームで選択されているレコードを削除する事ができます。

メインフォーム!サブフォーム名!.Form RecordsetClone

特定のレコードを一度に削除する(SQL) †

Private Sub cmd削除_Click()
  Dim mySQL As String
  Dim ret As Integer
  Dim cn As New ADODB.Connection
  Dim com As New ADODB.Command
  
  mySQL = "DELETE * from T_顧客 WHERE 都道府県 = '" & Me!txt条件 & "'"
  
  Set cn = CurrentProject.Connection
  com.ActiveConnection = cn
  com.CommandText = mySQL
  com.Execute
  
  Me.Requery
  
End Sub

入力値のチェック †

入力された値が不正な時に再入力を促す †

テキストボックスに値を入力すると、下記の順番にイベントが発生します。

Private Sub 商品名_BeforeUpdate(Cancel As Integer)
 Dim ret As Integer
 
 Beep
 ret = MsgBox(Me!商品名 & vbCrLf & "入力した値は正しいですか", vbQuestion + vbOKCancel, "入力検査")
 
 Select Case ret
   Case vbOK
   Case vbCancel
     Cancel = True
 End Select
End Sub

文字数を調べる（Len) †

Len関数を利用すると、文字数を調べる事ができます。

書式

retvalue = Len(sring)

retvalue   :戻り値(Long型). 取得した文字
string     :文字数を調べる文字列

例
```
ret = Len(Me!商品名)
```

len(Me!商品名)

文字を抜き出す(Left) †

Left関数を利用すると、テキストボックスに入力された文字列の左端から、指定した文字数を取得

書式

retvalue = Left(string, length)

retvalue   :戻り値(String型). 取得した文字
strign     :調べる文字列
length     :取得する文字数

例
```
ret = Left(Me!商品番号,1)
```

値が重複していないかどうか調べる(DLookup) †

DLookup関数を利用すると、レコードセットの中に指定した値があるかどうかを調べる事ができます。

書式

retvalue = DLookup(expr, domain, criteria)

retvalue   :戻り値(String型) レコードセットに含まれるフィールド値
expr       :フィールド名
domain     :テーブル名、クエリ名
criteria   :値を検索する条件式を表す文字列

例
[T_商品]テーブルの[商品番号]フィールドに「A0001」という値が登録されているかどうか
下記の場合値がある時は「A0001」、値が見つからない場合「Null」になります。
```
ret = DLookup("商品番号", "T_商品", "商品番号 = 'A0001'")
```

入力されていないコントロールがあるときに更新作業を取り消す †

フォーム上のコントロールは、Controlsコレクションで管理されています。

For Each control in Controls
 ・
 ・
 ・
Next

上記を繰り返せば、フォーム上の全てのコントロールにアクセスする事ができます。
コントロールのタイプは、ControlオブジェクトのControlTypeプロパティで参照する事ができます。

例

Private Sub Form_BeforeUpdate(Cancel As Integer)
  Dim ctrl As Control
  Dim str As String
  Dim ret As Integer
  str = ""
  For Each ctrl In Me.Controls     '--------------------------①
    If ctrl.ControlType = acTextBox Then  '-------------------②
      If IsNull(ctrl) Then                '-------------------③
        str = str & ctrl.Name & " "       '-------------------④
      End If
    End If
  Next
  
  If str <> "" Then  '----------------------------------------⑤
    Beep
    ret = MsgBox(str & vbCrLf & "入力されていません", _
    vbExclamation + vbOKCancel, "入力検索")
    
    Select Case ret
      Case vbOK
        '何もしない
      Case vbCancel
        Cancel = True '---------------------------------------⑥
    End Select
  End If
End Sub

①フォーム上のすべてのコントロールを参照する繰り返し
②参照のコントロールがテキストボックスの場合
③テキストボックスの値がNullかどうか調べる
④str変数にコントロール名を追加していく
⑤変数strが初期値("")以外の時は、メッセージボックスでコントロール名を表示する。
⑥[キャンセル]ボタンが選択されたときは、フォームでの更新操作を取り消す

アプリケーション構築のヒント †

フォームにファンクションキーを追加する †

フォームの[キークリック時/KeyDown]プロパティにプロシージャを作成

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
    Select Case KeyCode
      Case vbKeyF1
        Call cmd抽出_Click
      Case vbKeyF2
        Call cmd解除_Click
    End Select
End Sub

フォームの[キーイベント取得]プロパティを「はい」にしておく

主なキーコード
キーキーコード定数
[F1] vbKeyF1
[F2] vbKeyF2
[Insert] vbKeyInsert
[Delete] vbKeyDelete
↑ vbKeyUp
↓ vbKeyDown

キー	キーコード定数
[F1]	vbKeyF1
[F2]	vbKeyF2
[Insert]	vbKeyInsert
[Delete]	vbKeyDelete
↑	vbKeyUp
↓	vbKeyDown

入力した値によってフォーカスを移動する †

オブジェクトのSetFocusメソッドを利用すると、そのオブジェクトにフォーカスを移動する事ができる。

書式
```
object.Setfocus
```

例
郵便番号が入力されれば、住所2にフォーカスを移動
乳便番号が入力されなければ、住所1に

Private Sub 郵便番号_AfterUpdate()
  If IsNull(Me!郵便番号) Then
    Me.住所1.SetFocus
  Else
    Me.住所2.SetFocus
  End If
End Sub

次のページにフォーカスを移動する †

FormオブジェクトのGoToPageメソッドを利用すると指定したページの先頭オブジェクトにフォーカスを移動する事ができます。

書式

form.GoToPage pagenumber, right, down

pagenumber    :移動先のページ番号
right         :(省略可)表示するページの左端の水平方向のオフセット(twip単位)
down          :(省略可)表示するページの上橋の水平方向のオフセット(twip単位）

例

Private Sub fra住所_AfterUpdate()
  Debug.Print Me.fra住所
  Select Case Me!fra住所
    Case 1: Me.GoToPage 1
    Case 2: Me.GoToPage 2
  End Select
End Sub

コントロールの使用可能/付加を切り替える †

コントロールの[使用可能]プロパティを「いいえ」にすると、そのコントロールは実行時にフォーカスを移動する事ができなくなります。
[使用可能]プロパティの英語表記は「Enable」です。

例

Me!cmd抽出.Enable = False   '使用不可
Me!cmd抽出.Enable = True    '使用可

コントロールの表示/非表示を切り替える †

コントロール[可視]プロパティを「いいえ」にすると、そのコントロールは非表示になります。
[可視]プロパティの英語表記は「Visible」です。

例

If IsNull(Me!txtキー) Then
  M!cmd抽出.Visible = False  '----非表示
Else
  Me!cmd抽出.Visible = True  '---表示
End If

データベースウィンドウを最小化する †

DoCmdオブジェクトの下記のメソッドを利用すると、カレントウィンドウのサイズを変更する事ができます。
これらのメソッドは、マクロの[最小化][最大化][元のサイズに戻す]アクションと同じ処理を行います。

書式
```
DoCmd.Mimimize    :最小化
DoCmd.Maximize    :最大化
DoCmd.Restore     :元のサイズに戻す
```
これらは、カレントウィンドウのサイズを変更する処理を行います。
メソッドを実行する前に、サイズを変更するウィンドウのSetFocusを利用するかDoCmdオブジェクトのSelectObjectメソッドを利用して、そのウィンドウをアクティブな状態にしてください。
データベースウィンドウをアクティブにするには、SelectObjectメソッドのindatabasewindou引数をTrueにしてください。

DoCmdオブジェクトのSelectObjectメソッド

例

Private Sub cmd最小化_Click()
  DoCmd.SelectObject acTable, , True
  DoCmd.Minimize
End Sub

Private Sub cmd元のサイズ_Click()
  DoCmd.SelectObject acTable, , True
  DoCmd.Restore
  Me.SetFocus
End Sub

フォームが開いているかどうか調べる †

SysCmdメソッドを利用すると、指定したAccessオブジェクトが開いているかどうかを確認することができます。
オブジェクトが開いている場合は、そのビューも調べる事ができます。

書式

SysCmd(action, arg2, arg3)

action     :実行するアクションの種類
            Accessオブジェクトの状態を調べる時は「acSysCmdGetObjectState」
arg2       :状態を調べるオブジェクトの種類
            acTable       :テーブル
            acQuery       :クエリ
            acForm        :フォーム
            acReport      :レポート
            acMacro       :マクロ
            acModule      :モジュール
            acDataAccessPage :データアクセスページ
arg3       :状態を調べるオブジェクトの名前

例
「F_顧客」フォームの状態を調べる

SysCmd(acSysCmdGetObjectState, acForm, "F_顧客")

戻り値

定数                値         意味
                    0          閉じている
acObjStateOpen      1          開いている
acObjStateDirty     2          変更後保存されていない
acObjStateNew       3          新しい

オブジェクトのカレントビュー †

オブジェクトのカレントビューはCurrentViewプロパティで参照する事ができます。

例
「F_顧客」フォームのカレントビューを調べる

Forms("F_顧客").CurrentView

戻り値

値        ビュー
0         デザインビュー
1         フォームビュー
2         データシートビュー

例

Private Sub cmd確認_Click()
 Dim frmname As String
 Dim frmview As String
 
 frmname = Me.txt名前
 
 If SysCmd(acSysCmdGetObjectState, acForm, frmname) = 0 Then
   Beep
   MsgBox frmname & " は閉じてます", vbOKOnly + vbInformation, "確認"
 Else
   Select Case Forms(frmname).CurrentView
     Case 0:   frmview = "デザインビュー"
     Case 1:   frmview = "フォームビュー"
     Case 2: frmview = "データシートビュー"
   End Select
 
 Beep
 MsgBox frmname & " は開いています : " & frmview, _
 vbOKOnly + vbInformation, "確認"
 End If  
End Sub

コンボボックスのリストに値を追加する †

コンボボックスに存在しない値をテキストボックス部分に入力すると、リスト外入力時/NotInListイベントが発生します。
このとき独自のメッセージを表示して、入力した値をリストに追加する処理を実行できます。
cboグループの入力チェックを「はい」にする。

例

Private Sub cboグループ_NotInList(NewData As String, Response As Integer)
 Dim ret As Integer
 Dim cn As ADODB.Connection
 Dim rs As New ADODB.Recordset
 Debug.Print ret
 Response = acDataErrContinue   '-------------------------------------①
 Beep
 ret = MsgBox(NewData & " をリストに追加しますか", _
 vbYesNo + vbQuestion, "リスト追加")
 
 Select Case ret
   Case vbYes
     Set cn = CurrentProject.Connection
     rs.Open "商品テーブル", cn, adOpenKeyset, adLockOptimistic
     rs.AddNew "商品名", NewData  '-----------------------------------②
     Me.cboグループ = Null     '--------------------------------------③
     Me.cboグループ.Requery    '--------------------------------------④
   Case vbNo
     Me.cboグループ = Null
     Me.cboグループ.Dropdown
 End Select
End Sub

①NotInListプロシージャのResponse引数をacDataErrContinueにすると、システムメッセージを非表示にして、独自のメッセージを表示する事ができる。
②新規レコードを追加して、テキストボックス部分に入力された値を「商品名」フィールドに代入する
テキストボックスに入力された値は、NoInListプロシージャのNewData引数で参照する事ができます。
③テキストボックス部分を空にする
④コンボボックスの再クエリを実行する

処理に時間がかかる時に、ステータスバーにインジケータを表示する。 †

SysCmdメソッドを利用すると、ステータスバーに指定した文字列を表示したり、進捗状況を表すインジケータを表示する事ができます。

書式

SysCmd(action, arg2, arg3)

インジケータの初期化

action :acSysCmdInitMeter
arg2   :ステータスバーに表示する文字列
arg3   :インジケータの最大値

インジケータを更新

action :acSysCmdUpdateMeter
arg2   :インジケータの現在の値
arg3   :(設定しない)

インジケータを消去

action :acSysCmdRemoveMeter
arg2   :(設定しない)
arg3   :(設定しない)

例

Private Sub cmdスタート_Click()
 Dim i As Long
 Dim cnt As Long
 cnt = 10000000
 SysCmd acSysCmdInitMeter, "処理中", cnt
 For i = 0 To cnt
   SysCmd acSysCmdUpdateMeter, i
 Next i
 SysCmd acSysCmdRemoveMeter
 MsgBox "処理完了", vbOKOnly + vbInformation, "完了"
End Sub

処理に時間がかかる時にフォームにメッセージを表示する †

DoCmdオブジェクトのHourgLassメソッドを利用すると、マウスのポインタの形状を砂時計にすることができます。

書式

DoCmd.HourLass hourLasson

hourLasson   :砂時計ポインタを表示するかどうか
              True  :砂時計ポインタ
              False :通常ポインタ

コマンドボタンをクリックすると、下記の順番でイベントが発生します。

MouseDownイベント ⇒ MouseUpイベント ⇒ Clickイベント

例

Private Sub cmdスタート_Click()
 Dim i As Long
 Dim cnt As Long
 
 DoCmd.Hourglass True  '--------------------------------------①
 cnt = 10000000
 SysCmd acSysCmdInitMeter, "処理中", cnt
 For i = 0 To cnt
   SysCmd acSysCmdUpdateMeter, i
 Next i
 SysCmd acSysCmdRemoveMeter
 
 Me.lblメッセージ.Visible = False '---------------------------②
 DoCmd.Hourglass False '--------------------------------------③
 MsgBox "処理完了", vbOKOnly + vbInformation, "完了"
End Sub

Private Sub cmdスタート_MouseDown(Button As Integer, _
Shift As Integer, X As Single, Y As Single)
 Me.lblメッセージ.Visible = True  '--------------------------④
End Sub

Private Sub Form_Open(Cancel As Integer)
 Me.lblメッセージ.Visible = False
End Sub

①ポインタの形状を砂時計にする
②lblメッセージラベルを非表示にする
③ポインタの経常を通常に戻す
④lblメッセージラベルを表示する

日付をアップダウンするボタンを作成する †

Visual BasicのDataAdd関数を利用すると、指定した時間間隔を加算または減算した日付を取得する事ができます。

書式

retvalue = DataAdd(interval, number, date)

retvalue    :戻り値(String型) 加算また減算した日付
interval    :追加する時間間隔を表す文字列式
             yyyy :年
             m    :月
             d    :日
number      :追加する時間間隔の数
date        :時間間隔を追加する日付

例1
今日の日付から10日後の日付を取得する
```
ret = DateAdd("d", 10, Date)
```

例2
今日の日付から10日前の日付を取得する
```
ret = DateAdd("d", -10, Date)
```

日付をアップダウンするボタン

Private Sub Form_Open(Cancel As Integer)
 Debug.Print "てすと"
 Me.txt日付 = Date
End Sub

Private Sub cmdDec_Click()
 Me.txt日付 = DateAdd("d", -1, Me.txt日付)
End Sub

Private Sub cmdInc_Click()
 Me.txt日付 = DateAdd("d", 1, Me.txt日付)
End Sub

コンパイルエラーが出る
VisualBasic Editorで、「ツール」⇒「参照設定」⇒参照不可ってのにチェックが入っていたので、それを外すと治った。

ADOのレコードセットをフォームに表示する †

フォームのRecordsetプロパティにADOのRecordsetオブジェクトへの参照を代入すると、Recordsetオブジェクトの内容をフォームに表示する事ができます。

Set forms!form.Recordset = recordset

ADOのレコードセットはフォーム上で編集する事ができません。
編集する必要がある場合は、DAOを利用してください。

例

Private Sub txtキー_AfterUpdate()
 Dim cn As ADODB.Connection
 Dim rs As New ADODB.Recordset
 Dim mySQL As String
 
 mySQL = "SELECT * FROM T_商品 WHERE 商品グループ = '" & Me.txtキー & "'"
 Set cn = CurrentProject.Connection
 rs.Open mySQL, cn, adOpenKeyset, adLockOptimistic
 Set Me.Recordset = rs
 
 rs.Close: Set rs = Nothing: cn.Close: Set cn = Nothing
End Sub

DAOのレコードセットをフォームに表示する †

フォームのRecorsetプロパティにDAOのRecordsetオブジェクトへの参照を代入すると、Recordsetオブジェクトの内容をフォームに表示する事ができます。

Set forms!form.Recorset = recordset

DAOを利用するには

例

Private Sub txtキー_AfterUpdate()
 Dim db As DAO.Database
 Dim rs As DAO.Recordset
 Dim mySQL As String
 Set db = CurrentDb()
 mySQL = "SELECT * FROM T_商品 WHERE 商品グループ Like '" & Me.txtキー & "*'"
 Set rs = db.OpenRecordset(mySQL)
 Set Me.Recordset = rs
 Set rs = Nothing: Set db = Nothing
End Sub

独自のレコード移動ボタンを作る †

フォームのRecordsetプロパティは、フォームに表示しているレコードソースそのものを参照します。
RecordsetオブジェクトのMove系のメソッドを使って、カレントコードを移動する事ができます。

例

'フォームを[開く時/Open]
Private Sub Form_Open(Cancel As Integer)
 Me.Recordset.MoveLast
 Me.Recordset.MoveFirst
End Sub
'フォームの[レコード移動時/Current]
Private Sub Form_Current()
 Me.txt情報 = Me.CurrentRecord & " / " & Me.Recordset.RecordCount
End Sub

Private Sub cmd先頭_Click()
 Me.Recordset.MoveFirst
End Sub

Private Sub cmd前_Click()
 Me.Recordset.MovePrevious
End Sub

Private Sub cmd次_Click()
 Me.Recordset.MoveNext
End Sub

Private Sub cmd最終_Click()
 Me.Recordset.MoveLast
End Sub

他形式のファイルをインポートする †

DoCmdオブジェクトのTransferSpreadsheetメソッドを利用すると、計算アプリケーションで作成したファイルからデータを読み込む事が出来ます。
また、TransferTextメソッドを利用すると、CSV形式のファイルからデータを読み込む事ができます。
このときVisual BasicのDir関数を利用すると、インポート元のファイルが存在するかどうか調べる事ができます。

TransferSpreadsheetメソッド
表計算アプリケーションで作成したファイルからデータを読み込み、テーブル追加する処理を行います。
マクロの[ワークシート変換]アクションと同じ処理です。

書式

DoCmd.TransferSpreadsheet transfertype, spreadsheettype, tablename, filename, hasfieldnames, range

transfertype        :変換の種類
                     インポートの時は「aclmport」
spreadsheettype     :ワークシートのタイプ
                     Excel形式のファイルをインポートするときは「acSpreadsheettypeExcel8」
                     または「acSpreadsheetTypeExcel9」
tablename           :インポートしたデータを保存するテーブル名
filename            :インポートするファイル名
hasfieldnames       :(省略可)ファイルの先頭行をフィールド名に使用するかどうか
range               :(省略可)読み込む範囲

例
「D:\Sample.xls」から読み込んだデータを[サンプル]テーブルに追加する。
```
DoCmd.TransferSpreadsheet acImport, acSpreadsheetTypeExcel8, "サンプル", "D:\Sample.xls"
```

TransferTextメソッド
CSV形式のファイルからデータを読み込む時には、TransferTextメソッドを利用します。

書式

DoCmd.TransferText transfertype, specificationname, tablename, filename, hasfieldnames, htmltablename, codepage

transfertype        :変換の種類
                     CSV形式のファイルからインポートするときは、「acImportDelim」
specificationname   :(省略可)定義ファイル名
tablename           :インポートしたデータを保存するテーブル名
filename            :インポート元のファイル名
hasfieldnames       :(省略可)ファイルの先頭行をフィールド名にしようするかどうか
htmltablename       :(設定しない)
codepage            :(省略可)コードページの文字セット

例
「D:\Sample.csv」から読み込んだデータを[サンプル]テーブルに追加する
```
DoCmd.TransferText acImportDelim,,"サンプル","D:\Sample.csv"
```

Dir関数 [#m3948c38] システムにファイルが存在するかどうか
書式
```
retvalue = Dir(pathname)

retvalue  :戻り値(String型)
pathname  :調べるファイルのパス名
```
Dir関数は、指定したファイルが見つかった場合にはファイル名を返します。もしも見つからなかった場合には、長さ0の文字列("")を返します。

例 [Me.txtファイル]に指定したファイルを[Me.txtテーブル]に指定したテーブルにインポートする。

Private Sub cmdインポート_Click()
 Dim ext As String
 
 If IsNull(Me.txtファイル) Or IsNull(Me.txtテーブル) Then
   Beep
   MsgBox "インポートするファイルと、インポート先テーブル名が入力されておりません。", _
         vbOKOnly + vbExclamation, "インポート"
   Exit Sub
 End If
 
 'ファイルがあるかどうかチェック
 If Dir(Me.txtファイル) = "" Then
   Beep
   MsgBox "ファイルが見つかりません", vbOKOnly + vbExclamation, "インポート"
   Exit Sub
 End If
 
 '拡張子をチェックしてインポート
 ext = Right(Me.txtファイル, 3)
 Select Case ext
   Case "xls"
     DoCmd.TransferSpreadsheet acImport, acSpreadsheetTypeExcel8, _
     Me.txtテーブル, Me.txtファイル, True
   Case "csv"
     DoCmd.TransferText acImportDelim, , _
     Me.txtテーブル, Me.txtファイル, True
   Case Else
     Beep
     MsgBox "指定したファイルはインポートできません。", vbOKOnly + vbExclamation, "インポート"
 End Select
 
 Beep
 MsgBox "インポート完了", vbOKOnly + vbInformation, "インポート"
End Sub

テーブルを他形式のファイルにエクスポートする †

テーブルに登録されているレコードやクエリの結果を他形式のファイルにエクスポートする時も、CoCmdオブジェクトのTransferSpreadsheetメソッドとTransferTextメソッドを利用します。

例(TransferSpreadsheetメソッド)
Excel形式のファイルにエクスポートするときは、transfertype引数をacExportにする
[T_商品]テーブルの内容を「D:\Access\商品一覧.xls」に出力する Excel形式のファイルにエクスポートするときは、transfertype引数をExportにする。
```
DoCmd.TransferSpreadsheet acExport, acSpreadSheetType8, "T_商品", "D:\Access\商品一覧"
```

例(TransferTextメソッド)
CSV形式のファイルにエクスポートするときは、transfertype引数をacExportDelimにする
[T_商品テーブル]の内容を「D:\Access\商品一覧.csv」に出力する
```
DoCmd.TransferText acExportDelim, , "T_商品", "D:\Access\商品一覧.csv"
```

例
テーブルまたは、クエリの結果を、指定したファイルにエクスポートする

Private Sub cmdエクスポート_Click()
On Error GoTo Err_cmdエクスポート_Click

 Dim ext As String
 Dim ret As Integer
 
 'テーブル名、エクスポート先ファイル名が入力されているかどうか
   If IsNull(Me.txtテーブル) Then
     Beep
     MsgBox "テーブル名か、エクスポート先のファイル名が入力されておりません." _
     , vbOKOnly + vbExclamation, "エクスポート"
     Exit Sub
   End If
 
 'ファイルがあるかどうか
 If Dir(Me.txtファイル) = "" Then
   
 Else
   Beep
   ret = MsgBox("指定したファイルは既に存在します。" & vbCrLf _
   & "上書きしますか", _
   vbYesNo + vbQuestion, "エクスポート")
   
   Select Case ret
   Case vbYes
     
   Case vbNo
     Beep
     MsgBox "ファイル名を入力し直してください", _
     vbOKOnly + vbInformation, "エクスポート"
     Exit Sub
   End Select
 End If
 
 '形式/拡張子をチェックしてエクスポート
 ext = Right(Me.txtファイル, 3)
 Select Case fra形式
   Case 1
     If ext = "xls" Then
       DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel8, _
         Me.txtテーブル, Me.txtファイル, True
     Else
       Beep
       MsgBox "拡張子が不正です。", vbOKOnly + vbExclamation, "エクスポート"
       Exit Sub
     End If
   Case 2
     If (ext = "csv") Or (ext = "txt") Then
       DoCmd.TransferText acExportDelim, , Me.txtテーブル, Me.txtファイル, True
     Else
       Beep
       MsgBox "拡張子が不正です。", vbOKOnly + vbExclamation, "エクスポート"
     End If
 End Select
 
 Beep
 MsgBox "エクスポートを終了しました", vbOKOnly + vbInformation, "エクスポート"

Exit_cmdエクスポート_Click:
 Exit Sub
Err_cmdエクスポート_Click:
 Beep
 MsgBox Err.Number & " : " & Err.Description
 Resume Exit_cmdエクスポート_Click:
End Sub

カレントコードを移動する †

DoCmdオブジェクトのGoToRecordメソッドを利用すると、指定したレコードをカレントコードにすることができます。
マクロの「レコードの移動」アクションと同じ処理です。

書式

DoCmd.GoToRecord objecttype, objectname, record, offset

objecttype   :(省略可)オブジェクトの種類
objectname   :(省略可)オブジェクト名
record       :移動先のレコード
              acFirst    :先頭レコードへ
              acPrevious :ひとつ前のレコードへ
              acNext     :次のレコード(既定値)
              acLast     :最終レコードへ
              acNewRec   :新規レコードへ
              acGoTo     :指定したレコードへ
offset       :(省略可)移動するレコード数

ファイルに出力する方法 †

ファイルを出力モードで開く(Openステートメント)
データを出力する(Write #ステートメント)
ファイルを閉じる(Closeステートメント)

Openステートメント
指定したファイルを開いて、データを入出力できるようにします。

書式

Open passname For mode As #filenumber

passname    :出力先のファイル名
mode        :ファイルモード(出力用に開くときは「Output」)
finenumber  :ファイルを識別する番号

例
「D:\Access\Sample.csv」を出力モードで開く(ファイル番号は1)
```
Open "D:\Access\Sample.csv" For Output As #1
```

writeステートメント Outputモードで開いたファイルに、データを出力します。

書式

Write #filenumber, outputlist

finenumber  :開いているファイル番号
outputlist  :ファイルに出力するデータ

例

ファイルにレコードセットの「顧客ID」と「氏名」を出力する(ファイル番号は1)
Write #1, recordset!顧客ID, recordset!氏名

Closeステートメント
ファイルを閉じる処理を行います。

書式

Close #filenumber

finenumber  :開いているファイル番号

例
ファイルを閉じる(ファイル番号は1)
```
Close #1
```

ナビゲーション

検索

ツールボックス

最新の40件

AccessVBA/実例集

事例集 †

フォームの操作 †

指定したフォームを開く †

抽出したレコードをフォームに表示する。 †

新規レコード追加用にフォームを開く †

フォームの標題を変更する †

フォームの位置を指定する †

フォームの大きさで表示する †

予定時刻にアラームを表示する †

フォームを閉じる †

フォームを連動させる †

2つのフォームを連動させる †

フォームにキャンセルボタンを追加する †

一定時間経過後にフォームを閉じる †

レポートの操作 †

倍率を指定してプレビューする †

レポートのタイトルを印刷時に指定する †

1レコードごとに色分けして印刷する †

印刷前に「ページ設定」ダイアログボックスを表示する †

DoCmdオブジェクトのSelectObjectメソッドは、マクロの「オブジェクトの選択」アクションと同じ処理を行います。 †

印刷する前に[印刷]ダイアログボックスを表示する。 †

印刷するデータがない時に処理を中止する †

レコードを検索する †

検索ダイアログボックスを利用する †

フォームに検索機能を追加する †

コンボボックスの値を使って検索する †

あいまいな条件で検索する †

連続して検索する †

独自の検索置換パネルを作成する †

レコードを抽出する †

フォームにフィルタ機能を追加 †

抽出したレコードをリストボックスに表示する †

抽出したレコードをコンボボックスに表示 †

抽出したレコードをサブフォームに表示する †

複数の条件を使って検索する †

タブコントロールを使って抽出 †

トグルボタンを使って抽出する †

ボタンなどの「サイズ・配置」を揃えたい †

フォームに並べ替え機能を追加する †

レコードを削除する †

サブレコード上のレコードを削除する †

特定のレコードを一度に削除する(SQL) †

入力値のチェック †

入力された値が不正な時に再入力を促す †

文字数を調べる（Len) †

文字を抜き出す(Left) †

値が重複していないかどうか調べる(DLookup) †

入力されていないコントロールがあるときに更新作業を取り消す †

アプリケーション構築のヒント †

フォームにファンクションキーを追加する †

入力した値によってフォーカスを移動する †

次のページにフォーカスを移動する †

コントロールの使用可能/付加を切り替える †

コントロールの表示/非表示を切り替える †

データベースウィンドウを最小化する †

フォームが開いているかどうか調べる †

オブジェクトのカレントビュー †

コンボボックスのリストに値を追加する †

処理に時間がかかる時に、ステータスバーにインジケータを表示する。 †

処理に時間がかかる時にフォームにメッセージを表示する †

日付をアップダウンするボタンを作成する †

ADOのレコードセットをフォームに表示する †

DAOのレコードセットをフォームに表示する †

独自のレコード移動ボタンを作る †

他形式のファイルをインポートする †

テーブルを他形式のファイルにエクスポートする †

カレントコードを移動する †

ファイルに出力する方法 †